tek/Justfile

upstreams    := "codeberg origin" # TODO!
debug        := "reset && cargo run --"
release      := "reset && cargo run --release --"
name         := "-n tek"
bpm          := "-b 174"
midi-in      := "-i 'Midi-Bridge:.*nanoKEY.*:.*capture.*'"
midi-out     := "-o 'Midi-Bridge:.*playback.*'"
audio-in     := "-l 'Komplete Audio 6 Pro:capture_AUX1' -r 'Komplete Audio 6 Pro:capture_AUX1'"
audio-out    := "-L 'Komplete Audio 6 Pro:playback_AUX1' -R 'Komplete Audio 6 Pro:playback_AUX1'"
firefox-in   := "-l 'Firefox:output_FL' -r 'Firefox:output_FR'"
covfig       := "CARGO_INCREMENTAL=0 RUSTFLAGS='-Cinstrument-coverage' RUSTDOCFLAGS='-Cinstrument-coverage' LLVM_PROFILE_FILE='cov/cargo-test-%p-%m.profraw'"
grcov-binary := "--binary-path ./target/coverage/deps/"
grcov-ignore := "--ignore-not-existing --ignore '../*' --ignore \"/*\" --ignore 'target/*'"

default:
  bacon -s
tui:
  cargo run --example tui
cloc:
  for src in {cli,edn/src,input/src,jack/src,midi/src,output/src,plugin/src,sampler/src,tek/src,time/src,tui/src}; do echo; echo $src; cloc --quiet $src; done
test:
  cargo test --workspace --exclude jack
prof:
  CARGO_PROFILE_RELEASE_DEBUG=true cargo flamegraph -- arranger
doc:
  cargo doc -j4 --workspace --document-private-items
cov:
  {{covfig}} time cargo test -j4 --workspace --exclude jack --profile coverage
  rm -rf target/coverage/html || true
  {{covfig}} time grcov . -s . {{grcov-binary}} {{grcov-ignore}} -t html -o target/coverage/html
cov-md:
  {{covfig}} time cargo test -j4 --workspace --exclude jack --profile coverage
  {{covfig}} time grcov . -s . {{grcov-binary}} {{grcov-ignore}} -t markdown | sort
llcov:
  time cargo llvm-cov --workspace --exclude jack --profile coverage --no-report
  time cargo llvm-cov --workspace --exclude jack --profile coverage --no-report --doc
  time cargo llvm-cov report --doctests --html #--output-path target/coverage/html
amend:
  git commit --amend
push:
  git push -u codeberg main && git push -u origin main
tpush:
  git push --tags -u codeberg && git push --tags -u origin
fpush:
  git push -fu codeberg main && git push -fu origin main
ftpush:
  git push --tags -fu codeberg && git push --tags -fu origin

run:
  {{debug}}
release:
  {{release}}
build-release:
  time cargo build -j4 --release

clock:
  {{debug}} {{name}} {{bpm}} clock
clock-release:
  {{release}} {{name}} {{bpm}} clock

arranger:
  {{debug}} {{name}} {{bpm}} arranger
arranger-ext:
  {{debug}} {{name}} {{bpm}} {{midi-in}} {{midi-out}} arranger
arranger-release:
  {{release}} {{name}} {{bpm}} arranger
arranger-release-ext:
  {{release}} {{name}} {{bpm}} {{midi-in}} {{midi-out}} arranger

groovebox:
  {{debug}} {{name}} {{bpm}} groovebox
groovebox-ext:
  reset
  {{debug}} {{name}} {{bpm}} {{midi-in}} {{midi-out}} {{audio-in}} {{audio-out}} groovebox
groovebox-release:
  {{release}} {{name}} {{bpm}} groovebox
groovebox-release-ext:
  {{release}} {{name}} {{bpm}} {{midi-in}} {{midi-out}} {{audio-in}} {{audio-out}} groovebox
groovebox-release-ext-browser:
  {{release}} {{name}} {{bpm}} {{midi-in}} {{firefox-in}} {{audio-out}} groovebox

sequencer:
  {{debug}} {{name}} {{bpm}} sequencer
sequencer-ext:
  {{debug}} {{name}} {{bpm}} {{midi-in}} {{midi-out}} sequencer
sequencer-release:
  {{release}} {{name}} {{bpm}} sequencer
sequencer-release-ext:
  {{release}} {{name}} {{bpm}} {{midi-in}} {{midi-out}} sequencer

mixer:
  {{debug}} mixer
track:
  {{debug}} track
sampler:
  {{debug}} sampler
plugin:
  {{debug}} plugin